HW #4 Solutions

Here is a trick for defining positive constants. Whenever Simplify or Integrate are used, these assumptions will be applied.

$Assumptions={ℏ>0,m>0,ω>0,l>0}

Since we will be calculating ΔxΔp several times over, it is convenient to define a general function for doing so.  The Module command allows a function to use a number of different intermediate steps before returning its final value.  In this case, the values of ⟨(x^2)⟩ , ⟨x⟩, and  ⟨(p^2)⟩ are first calculated and put in the local variable xsq, xx, and psq (No need to calculate ⟨p⟩ because the wavefunctions are all real).  Then ΔxΔp is calculated from those.

ΔxΔp[psi_]:=Module[{xsq,xx,psq},{xsq,xx,psq}=((Integrate[psi{(x^2)psi,x psi,-(ℏ^2) D[psi,{x,2}]},{x,-∞,∞}])/(Integrate[(psi^2),{x,-∞,∞}]));(Sqrt[(xsq-(xx^2)) psq])
]

define the simple harmonic oscillator wavefunctions

sho[n_]:=With[{y=(x/(Sqrt[(ℏ/(m ω))]))},HermiteH[n,y]Exp[-(y^2)/2]]

Problem 1: uncertainty product for first 4 states of the harmonic oscillator

Table[ΔxΔp[sho[n]],{n,0,3}]//Simplify

note that each successive state adds 1 ℏ to the uncertainty product

Problem 2: repeat for the particle in a box.

define the wavefunctions for the PIAB.  This uses the Piecewise function to define the wavefunctions everywhere.

piab[n_]:=(Piecewise[{{0, x<0}, {Sin[n π x/l], 0≤ x<l}, {0, x≥ l}}])

Table[ΔxΔp[piab[n]],{n,1,4}]//Simplify

%//N (*numerical values*)

notice that the values are pretty close to those of the harmonic oscillator.  Each successive energy level adds a little less than 1 ℏ.

Problem 3

note that the odd sho wavefunctions are solutions to the Schrodinger Eqn with ψ(0)=0, which is exactly what we need for this problem.  Thus E=(2n+1+1/2)ℏω=(2n+3/2)ℏω.  The corresponding eigenfunctions are (Subscript[H, 2n+1])((Sqrt[((m ω)/ℏ)])x)(e^(-((m ((ωx)^2))/(2ℏ)))).

Problem 4

now define the half-harmonic oscillator wavefunctions

sho2[n_]:=With[{y=(x/(Sqrt[(ℏ/(m ω))]))},Piecewise[{{HermiteH[2n+1,y]Exp[-(y^2)/2],y>0},{0,y≤0}}]]

Table[ΔxΔp[sho2[n]],{n,0,3}]//N//Simplify

Problem 5

((Integrate[x ((sho2[9])^2),{x,0,∞}])/(Integrate[((sho2[9])^2),{x,0,∞}]))//Simplify//N

classical solution:  x(t)=(Subscript[x, T])|sinωt|.  Classical turning pt at energy E is (Subscript[x, T])=(Sqrt[((2E)/((mω)^2))])=(Sqrt[((2ℏω(2n+3/2))/((mω)^2))])=(Sqrt[((39ℏ)/(m ω))]).
The time average is

Integrate[(Sqrt[((39ℏ)/(m ω))])((Sin[ω t])/(π/ω)),{t,0,(π/ω)}]//N

which is amazingly close.  Both classical and quantum theories of harmonic oscillators give similar answers, except for the key difference which is only certain energies being allowed in the quantum theory.

Problem 6, BD 3.6

conj[x_]:=x/.Complex[a_,b_]->Complex[a,-b]

ψ1[x_]=Exp[I k x]+AA Exp[-I k x];ψ2[x_]=BB Exp[I q x]+CC Exp[-I q x];ψ3[x_]=DD Exp[I k x];

a)

continuity={ψ1[-a]==ψ2[-a],ψ1'[-a]==ψ2'[-a],ψ2[a]==ψ3[a],ψ2'[a]==ψ3'[a]}

b)

sol=Solve[continuity,{AA,BB,CC,DD}]//Flatten

T=(DD/.sol)conj[DD/.sol]//ExpToTrig//Simplify

R=(AA/.sol)conj[AA/.sol]//ExpToTrig//Simplify

T+R//Simplify

c)  0 when Sin[2 q a]=0, so 2 q a=m π.  The wavelength inside the well is λ=2π/q, so this condition is mλ/2=2a, i.e. an integer multiple of half-waves exactly fits into the box; if one just looked at the wave in the outer regions it is as if the well weren’t there.
The Ramsauer-Townsend effect occurs because the electron wavelength just fits inside the box.

d)

(Subscript[V, 0])=(((((ℏc))^2)(q^2))/(2mcsq))-energy//.{ℏc->1973 eV Å,mcsq->511000 eV,q->(π/(2 a )),a->1. Å,energy->0.7 eV}

Clear[V]

(Subscript[V, 0])

e)

use scaled variables u=2(Subscript[mV, 0])/(((ℏa))^2), e=E/(Subscript[V, 0])

R1=R/.{q->(1/a)(Sqrt[u+e]),k->(1/a)(Sqrt[e])}//Simplify

Series[R1,{e,0,1}]//Simplify

the reflection coefficient goes to 1 at low energy.  The shape of the reflection curve depends on the “area” u, but often goes to 1 for low energy.  This is called “quantum reflection”.

Plot[R1/.u->3,{e,0,10},PlotRange->{0,1},PlotStyle->Thick]

for fun, let’s plot the wavefunctions

sol1=sol/.{q->(1/a)(Sqrt[u+e]),k->(1/a)(Sqrt[e])}//Simplify

cond={q->(1/a)(Sqrt[u+e]),k->(1/a)(Sqrt[e]),u->2,e->3,a->1}

near the Ramsauer-Townsend resonance, virtually all transmitted

cond={q->(1/a)(Sqrt[u+e]),k->(1/a)(Sqrt[e]),u->2,e->7,a->1};Plot[Im[Piecewise[{{ψ1[x]/.sol1//.cond,x<-1},{ψ2[x]/.sol1//.cond,1>x>-1},{ψ3[x]/.sol1//.cond,x>1}}]],{x,-15,15}]

and now for very low energy, almost none transmitted

cond={q->(1/a)(Sqrt[u+e]),k->(1/a)(Sqrt[e]),u->2,e->.001,a->1};

Plot[Im[Piecewise[{{ψ1[x]/.sol1//.cond,x<-1},{ψ2[x]/.sol1//.cond,1>x>-1},{ψ3[x]/.sol1//.cond,x>1}}]],{x,-150,150}]

intermediate case

cond={q->(1/a)(Sqrt[u+e]),k->(1/a)(Sqrt[e]),u->2,e->2,a->1};

Plot[Re[Piecewise[{{ψ1[x]/.sol1//.cond,x<-1},{ψ2[x]/.sol1//.cond,1>x>-1},{ψ3[x]/.sol1//.cond,x>1}}]],{x,-15,15}]

Problem 7: Scattering in 2-d

a)

With[{ψ=(E^(I ky y))f[x]},
((-(ℏ^2))/(2m))((∂_(y,y))ψ+(∂_(x,x))ψ)+V[x]ψ==ℰ ψ
]//Simplify

part in parenthesis must be zero, so the effective Sch. Eq. for f is
 -(((ℏ^2) f''[x])/(2 m))+(V[x]+(((ky^2) (ℏ^2))/(2 m)))f[x]==ℰ f[x]
 Note that there is an effective potential energy that is increased as conparted to the normal potential energy by the (Subscript[p, y]) contribution to the kinetic energy.

b)  The potential is constant, independent of x, so try f[x]=Exp[i q x].  For simpler result, define (v^2)=2m (Subscript[V, 0])/(ℏ^2), ℰ=(ℏ^2)(k^2)/2m.  Plugging into the Sch. Eq.,

Solve[(((ℏ^2)(q^2))/(2 m))+((((ℏ^2)(v^2))/(2m))+(((ky^2) (ℏ^2))/(2 m)))==(((ℏ^2)(k^2))/(2 m)) ,q]

c ) q is imaginary if the stuff inside the (Sqrt[■]) is negative.  Using (k^2) - ((Subscript[k, y])^2)=((Subscript[k, x])^2)=(k^2)((Cos[θ])^2) gives Cos[θ]<v/k=(Sqrt[(Subscript[V, 0])/ℰ])
d) Since this problem is an effective 1-d problem, we can directly use the results we figure out in class:  the reflection probablity is 1 when the kinetic energy is less than the potential energy.  Again, this means Cos[θ]<(Sqrt[(Subscript[V, 0])/ℰ]).  If ℰ<(Subscript[V, 0]), the particles are always reflected. Above (Subscript[V, 0]), the larger ℰ is, the closer to glancing incidence the particles must be in order to reflect.