hydrogen atom Hamiltonian

(Subscript[H, l_])[f_]:=((-(ℏ^2))/(2 µ))D[f,{r,2}]+(((ℏ^2)l(l+1))/(2 µ (r^2)))f-((e^2)/r)f

Schrodinger equation

Sch[f_]:=(Subscript[H, l])@f==ℰ f

Sch[P0[r]]

educated guess for the ground state wavefunctions for different ls

Sch[(r^(l+1))(E^(-r/a))]//Simplify

to satisfy for all r, each power of r must separately vanish

Solve[{-2 a (1+l) (ℏ^2)+2 (a^2) (e^2) µ==0,r (ℏ^2)+2 (a^2) r ℰ µ==0},{a,ℰ}]

so the (Subscript[n, r])=0 energy levels for arbitrary l  are

E0[l_]:=-(((e^4) µ)/(2 (((1+l))^2) (ℏ^2)))
P0[l_]:=(r^(l+1))(E^(-r/a))/.a-> (((1+l) (ℏ^2))/((e^2) µ))

define “superpotential”

(Subscript[W, l_])[r]=((µ (e^2))/((l+1)(ℏ^2)))-((l+1)/r);

define operators analogous to SHO raising and lowering operators

(Subscript[A, l_])[f_]:=D[f,r]+(Subscript[W, l])[r]f

(Subscript[A†, l_])[f_]:=-D[f,r]+(Subscript[W, l])[r]f

Show that A†A and AA† are equal to (Subscript[H, l])-(Subscript[E, 0l])and (Subscript[H, l+1])-(Subscript[E, 0l])

(((ℏ^2)/(2µ))(Subscript[A†, l])@(Subscript[A, l])@P[r]==(Subscript[H, l])@P[r]-E0[l]P[r])//Simplify

(((ℏ^2)/(2µ))(Subscript[A, l])@(Subscript[A†, l])@P[r]==(Subscript[H, l+1])@P[r]-E0[l]P[r])//Simplify

now in terms of the principal quantum number n:

Enl[n_,l_]:=-(((e^4) µ)/(2 (n^2) (ℏ^2)))

P[n_,l_]:=Module[{P0l=P0[n-1]},Do[P0l=(Subscript[A†, lp])@P0l,{lp,n-2,l,-1}];P0l]

verify that the wavefunctions satisfy the Schrodinger eqn, and print them out.  They are unnormalized.

With[{n=17,l=10},Print[((Subscript[H, l])@P[n,l]==Enl[n,l]P[n,l])//Simplify];P[n,l]/.µ->(( (ℏ^2))/((e^2) (Subscript[a, B])))//Simplify]